@echo off
setlocal

set CWD=%~dp0

:: VIM Files
if exist "%userprofile%\vimfiles" (
    set /P confirm=Will delete existing "%userprofile%\vimfiles". OK with that? Press CTRL-C to abort.
    rmdir /Q /S "%userprofile%\vimfiles"
)

if exist "%userprofile%\_vimrc" (
    set /P confirm=Will delete existing "%userprofile%\_vimrc". OK with that? Press CTRL-C to abort.
    del /Q "%userprofile%\_vimrc"
)
echo set runtimepath+=%CWD:\=/%vim > "%userprofile%\_vimrc"
echo source %CWD:\=/%vim/vimrc >> "%userprofile%\_vimrc"

:: Mercurial Files
if exist "%userprofile%\mercurial.ini" (
    set /P confirm=Will delete existing "%userprofile%\mercurial.ini". OK with that? Press CTRL-C to abort.
    del /Q "%userprofile%\mercurial.ini"
)
echo %%include %CWD%hgrc\hgrc > "%userprofile%\mercurial.ini"
echo [ui] >> "%userprofile%\mercurial.ini"
echo ignore = %CWD:\=/%hgrc/hgignore >> "%userprofile%\mercurial.ini"
echo [extensions] >> "%userprofile%\mercurial.ini"
echo hggit = %CWD:\=/%lib/hg/hg-git/hggit/ >> "%userprofile%\mercurial.ini"
echo onsub = %CWD:\=/%lib/hg/onsub/onsub.py >> "%userprofile%\mercurial.ini"
echo allpaths = %CWD:\=/%lib/hg/allpaths/mercurial_all_paths.py >> "%userprofile%\mercurial.ini"
echo prompt = %CWD:\=/%lib/hg/hg-prompt/prompt.py >> "%userprofile%\mercurial.ini"
echo changelog = %CWD:\=/%lib/hg/changelog/changelog.py >> "%userprofile%\mercurial.ini"
echo evolve = %CWD:\=/%lib/hg/mutable-history/hgext/evolve.py >> "%userprofile%\mercurial.ini"
echo terse-status = %CWD:\=/%lib/hg/terse-status/terse-status.py >> "%userprofile%\mercurial.ini"
echo path-pattern = %CWD:\=/%lib/hg/path-pattern/mercurial_path_pattern.py >> "%userprofile%\mercurial.ini"

:: Git Files
if exist "%userprofile%\.gitconfig" (
    set /P confirm=Will delete existing "%userprofile%\.gitconfig". OK with that? Press CTRL-C to abort.
    del /Q "%userprofile%\.gitconfig"
)
echo [include] > "%userprofile%\.gitconfig"
echo path = %CWD:\=/%git/gitconfig >> "%userprofile%\.gitconfig"

:: Web Browser
if exist "%userprofile%\_pentadactylrc" (
    set /P confirm=Will delete existing "%userprofile%\_pentadactylrc". OK with that? Press CTRL-C to abort.
    del /Q "%userprofile%\_pentadactylrc"
)
echo set runtimepath=~/.pentadactyl,%CWD:\=/%pentadactyl > "%userprofile%\_pentadactylrc"
echo source %CWD:\=/%pentadactyl/pentadactylrc >> "%userprofile%\_pentadactylrc"

if exist "%userprofile%\_vimperatorrc" (
    set /P confirm=Will delete existing "%userprofile%\_vimperatorrc". OK with that? Press CTRL-C to abort.
    del /Q "%userprofile%\_vimperatorrc"
)
echo set runtimepath=~/.vimperator,%CWD:\=/%vimperator > "%userprofile%\_vimperatorrc"
echo source %CWD:\=/%vimperator/vimperatorrc >> "%userprofile%\_vimperatorrc"

:: Console 2
if exist "%appdata%\Console\console.xml" (
	set /P confirm=Will delete existing Console2 settings. OK with that? Press CTRL-C to abort.
	del /Q "%appdata%\Console\console.xml"
)
if not exist "%appdata%\Console" mkdir "%appdata%\Console"
copy "%CWD%console.xml" "%appdata%\Console\console.xml"

setx GIT_SSH=%USERPROFILE%\Dropbox\Utilities\plink.exe